Annonce

Bienvenue sur le site support des ouvrages :
SAS - Introduction au décisionnel : méthode et maîtrise du langage
(1ère édition - épuisée)
SAS - Introduction pratique : du data management au reporting (2ème édition - épuisée)
SAS - Introduction au décisionnel : du data management au reporting (3ème édition - épuisée (hélas...))

la réponse à la question "mais où trouver la 3ème édition ?" est précisée ici


Retrouvez dans ce tiré à part, la préface écrite par Mouloud Dey, Directeur Business solutions et marchés émergents, SAS France,
l’introduction générale ainsi que le plan complet de l’ouvrage

#1 04-01-2016 11:11:16

SAS-SR
Administrateur
Lieu: Université d'Orléans
Date d'inscription: 01-09-2008
Site web

La carte de voeux 2016 de www.sas-sr.com

Bonjour

le 4 janvier 2016, toutes les personnes inscrites sur ce site ont reçu cette carte de voeux pour l'année 2016 qui débute.

http://www.sas-sr.com/img/hny2016bm.png

Bien entendu, cette carte de voeux a été réalisée avec SAS (9.4 - M3) et voici le programme

Code:

title ; footnote ;

ods graphics / height=750 width=750 ; 

data test;
   x=5;
   y=5;
   y_flocon=3.6 ; flocon="Z";
   yt1=8 ;        texte1="www.sas-sr.com";
   yt2=6.5 ;      texte2=" vous souhaite ";
   yt3=5.5 ;      texte3="une excellente année";
   yt4=2.5 ;      texte4="2016" ;
run;

proc sgplot data=test aspect=1 noautolegend;
   xaxis min=0 max=10 offsetmin=0 offsetmax=0 display=none ;
   yaxis min=0 max=10 offsetmin=0 offsetmax=0 display=none  ;
   scatter x=x y=y / markerattrs=(symbol=squarefilled size=400 color=gold) dataskin=matte;
   scatter x=x y=y_flocon / markerchar=flocon markercharattrs=(Color=CXFFE762 Family="wwflakes" size=250);
   scatter x=x y=yt1 / datalabel=texte1 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CX5E40D6 family=times size=30pt Style=Italic);
   scatter x=x y=yt2 / datalabel=texte2 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=30pt Style=Italic);
   scatter x=x y=yt3 / datalabel=texte3 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=30pt Style=Italic);
   scatter x=x y=yt4 / datalabel=texte4 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=100pt Style=Italic);
run;

Pour obtenir un résultat identique au mien, vous devez :
1- disposer de SAS 9.4, 3ème révision (en raison de la présence de certaines options introduites avec cette dernière révision de SAS 9.4 - l'option ASPECT= de PROC SGPLOT et DATALABELPOS= en option de l'instruction SCATTER).
2- disposer des polices WWFLAKES et PWHAPPYNEWYEAR à télécharger sur http://www.dafont.com/fr/

L'option ASPECT= de PROC SGPLOT est mobilisée pour produire cette carte "carrée" : ASPECT= permet en effet de spécifier le ratio hauteur / largeur du graphique à produire.

La carte de voeux est ensuite composée de 6 éléments graphiques :

Le carré "fond jaune" est obtenu au moyen de l'instruction :

Code:

   scatter x=x y=y / markerattrs=(symbol=squarefilled size=400 color=gold) dataskin=matte;

C'est un simple marqueur de point "géant" (size=400...), le dégradé est obtenu au moyen de l'option DATASKIN=MATTE (voir page 336). L'option MARKERATTRS=() est présentée page 340.

Le "flocon" est obtenu au moyen de l'instruction suivante :

Code:

   scatter x=x y=y_flocon / markerchar=flocon markercharattrs=(Color=CXFFE762 Family="wwflakes" size=250);

Ce flocon, c'est la lettre Z (modalité de la variable FLOCON) utilisé comme marqueur d'un point (option MARKERCHAR=) et présentée au moyen de la police wwflakes  (MARKERCHARATTRS=()). Ces options ne sont pas présentées dans mon ouvrage (mais je me demande si elles étaient présentes dans la version de SAS 9.4 à ma disposition lors de la rédaction de mon ouvrage (SAS 9.4 M1)).

Les 4 lignes de texte sont ensuite obtenues au moyen des instructions suivantes :

Code:

   scatter x=x y=yt1 / datalabel=texte1 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CX5E40D6 family=times size=30pt Style=Italic);
   scatter x=x y=yt2 / datalabel=texte2 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=30pt Style=Italic);
   scatter x=x y=yt3 / datalabel=texte3 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=30pt Style=Italic);
   scatter x=x y=yt4 / datalabel=texte4 datalabelpos=center markerattrs=(symbol=plus size=0.1)
                       datalabelattrs=(color=CXFF0101 family=PWHappyNewYear size=100pt Style=Italic);

les textes à afficher sont en fait des modalités de variables que l'on va déclarer comme valeur de l'option DATALABEL=. La nouvelle option DATALABELPOS= permet de centrer ce texte (très utile cette nouvelle option !!!). L'option MARKERATTRS est mobilisée pour rendre le marqueur du point quasi invisible (SIZE=0.1)).

Au moyen de l'option DATALABELATTRS=(), on met en forme le texte. Cette option n'est pas évoquée dans mon ouvrage mais ici aussi, je ne sais pas si elle était déjà présente dans SAS 9.4 M1.

J'avais déjà réalisé une carte de voeux à destination des personnes inscrites sur www.sas-sr.com en 2010 (ça ne rajeunit personne...).

Cette carte, la voici :
http://www.sas-sr.com/img/voeux2010.png

C'était réalisé à l'époque avec SAS 9.2... et on constate que SAS a fait de gros progrès... non ?

Hors ligne

 

Pied de page des forums

Propulsé par FluxBB
Traduction par FluxBB.fr
Flux RSS